Queries

With the type aliases for DB objects set up, we can move forward to creating our first queries in Db module:

Db.fs

  23: 
  24: 

let getGenres (ctx : DbContext) : Genre list = 
    ctx.Public.Genres |> Seq.toList

getGenres is a function for finding all genres. The function, as well as all functions we'll define in Db module, takes the DbContext as a parameter. The : Genre list part is a type annotation, which makes sure the function returns a list of Genres. Implementation is straight forward: Using dot notation we can access all genres, and then just pipe it to Seq.toList to match the expected return type.

Db.fs

  26: 
  27: 
  28: 
  29: 
  30: 
  31: 
  32: 
  33: 

let getAlbumsForGenre genreName (ctx : DbContext) : Album list = 
    query { 
        for album in ctx.Public.Albums do
            join genre in ctx.Public.Genres on (album.Genreid = genre.Genreid)
            where (genre.Name = genreName)
            select album
    }
    |> Seq.toList

getAlbumsForGenre takes genreName as argument (inferred to be of type string) and returns a list of Albums. It makes use of "query expression" (query { }) which is very similar to C# Linq query. Read here for more info about query expressions. Inside the query expression, we're performing an inner join of Albums and Genres with the GenreId foreign key, and then we apply a predicate on genre.Name to match the input genreName. The result of the query is piped to Seq.toList.

Db.fs

  35: 
  36: 
  37: 
  38: 
  39: 
  40: 
  41: 

let getAlbumDetails id (ctx : DbContext) : AlbumDetails option = 
    query { 
        for album in ctx.Public.Albumdetails do
            where (album.Albumid = id)
            select album
    } 
    |> Seq.tryHead

getAlbumDetails takes id as argument (inferred to be of type int) and returns AlbumDetails option because there might be no Album with the given id. Here, the result of the query is piped to the Seq.tryHead function, which takes care to transform the result to option type. Seq.tryHead verifies if a query returned any result: If the sequence contains any element Seq.tryHead returns Some, otherwise None.

Show code from this section on GitHub